Copter | Коптер - Ресурсы -

С К И Л Л О В А Я С И Б И Р Ь

⛔ Сервер : С К И Л Л О В А Я С И Б И Р Ь Public: 37.230.137.147:27015

© skillpub.ru - 21 янв 2026, 08:38

Место свободно

Здесь вы сможете купить рекламу на данном форуме

Стоимость за 1 день 12 ₽

Copter | Коптер

: Copter_0.2.zip
223.96 КБ; Купить за 800 ₽; Другие ресурсы пользователя Kurtis

Mode SnowGame
Небольшой режим: снеговики против людей.

Flying Ghosts | Летающие Призраки
Развлекательный плагин.

Случайный волшебник
Каждый раунд среди команд выбирается случайный игрок. Этот игрок становится волшебником.

Медик

ДобавилKurtis • 21 дек 2025, 21:10
АвторKurtis
Версия0.2
Статистика 298 просмотров • 1 комментарий • 2 скачивания

Коптер с несколькими режимами.

Режимы:
1. Бездействие. Коптер просто висит в воздухе.
2. Атака противников. Коптер атакует противников в зоне видимости.
3. Ручное управление. Коптером можно управлять вручную, в том числе и стрелять на ЛКМ/ПКМ лазерами/ракетами.
4. Камикадзе. Коптер лежит к ближайшей цели и взрывается, нанося урон всем врагам в радиусе взрыва.

Улучшение:
1. Лечение. Лечит себя/союзников в зоне видимости.
2. Атака ракетами. Возможность коптера атаковать ракетами в режиме "Атака противников" и вручную на ПКМ в режиме "Ручное управление".

Немного скриншотов:

► Показать

Требования:
- AmxModX 1.9.0 и выше
- ReHLDS (последней версии)
- Reapi (последней версии)

Установка: 1. Извлечь содержимое из архива в папку *cstrike/* вашего сервера.
2. Скомпилировать исходник *.sma*, поместить скомпилированный *.amxx* плагин в папку cstrike/addons/amxmodx/plugins.ini.
3. Прописать название плагина в списке плагинов: *cstrike/addons/amxmodx/configs/plugins.ini* (copter.amxx).

Настройка

Код: Выделить всё

// Модель коптера
#define COPTER_MODEL "models/copter/copter.mdl"
// Модель ракеты
#define ROCKET_MODEL "models/rpgrocket.mdl"

// Звук полета коптера
#define COPTER_SOUND "copter/copter.wav"
// Звук выстрела коптера
#define COPTER_SOUND_LASER "copter/primary_laser.wav"
// Звук лечения коптера
#define COPTER_HEAL "items/medshot4.wav"
// Звук выпуска ракеты
#define COPTER_SOUND_ROCKET_FIRE "weapons/rocketfire1.wav"
// Звук полета ракеты
#define COPTER_SOUND_ROCKET_FLY "weapons/rocket1.wav"

// Раскоментируйте, чтобы включить фуллпак (добавляет немного реалистичности игроку при управлении коптером)
//#define FULLPACK_ON

copter_settings.cfg:

► Показать

Код: Выделить всё

// Настройки коптера

// Цена коптера
copter_cost			= 10000

// Здоровье коптера
copter_health			= 1500

// Сколько урона наносит коптер выстрелом
copter_damage			= 8

// Периодичность атаки коптера в секундах (1 раз в это время он может стрелять)
copter_period_damage		= 0.3

// Когда уничтожать коптер (1 - при убийстве владельца, 2 - в конце раунда, 3 - при убийстве владельца и в конце раунда)
copter_destroy_type		= 3

// Сколько урона наносит коптер при уничтожении
copter_destroy_damage		= 500

// Радиус для нанесния урона при уничтожении коптера
copter_destroy_radius		= 300

// Стоимость улучшения коптера для лечения (значение -1 отключает возможность такого улучшения)
copter_up_health_cost		= 2000

// Кого может лечить коптер при улучшении (1 - себя, 2 - себя и союзников)
copter_health_type		= 2

// Периодичность с которой лечит коптер в секундах
copter_health_period		= 5.0

// По сколько ХП лечит коптер
copter_health_value		= 5

// До скольки ХП лечит коптер
copter_health_max		= 100

// Стоимость улучшения коптера для возможности стрельбы ракетами (значение -1 отключает возможность такого улучшения)
copter_up_rocket_cost		= 6000

// Сколько урона наносит ракета коптера
copter_rocket_damage		= 200

// Периодичность атаки коптера ракетой в секундах (1 раз в это время он стреляет ракетой)
copter_rocket_period_damage	= 20.0

// Радиус для нанесния урона при взрыве ракеты
copter_rocket_exp_radius	= 200

Исходный код

Код: Выделить всё

#include <amxmodx>
#include <amxmisc>
#include <fakemeta_util>
#include <hamsandwich>
#include <reapi>

// Модель коптера
#define COPTER_MODEL "models/copter/copter.mdl"
// Модель ракеты
#define ROCKET_MODEL "models/rpgrocket.mdl"

// Звук полета коптера
#define COPTER_SOUND "copter/copter.wav"
// Звук выстрела коптера
#define COPTER_SOUND_LASER "copter/primary_laser.wav"
// Звук лечения коптера
#define COPTER_HEAL "items/medshot4.wav"
// Звук выпуска ракеты
#define COPTER_SOUND_ROCKET_FIRE "weapons/rocketfire1.wav"
// Звук полета ракеты
#define COPTER_SOUND_ROCKET_FLY "weapons/rocket1.wav"

// Раскоментируйте, чтобы включить фуллпак (добавляет немного реалистичности игроку при управлении коптером)
//#define FULLPACK_ON

const COPTER_IMPULSE = 555;

enum _: eCopterMode {
	Mode_Draw,
	Mode_Attack,
	Mode_Control,
	Mode_Kamikadze
};

enum _: eCopterSetting {
	CopterCost,
	Float: CopterHealth,
	Float: CopterDamage,
	Float: CopterDamagePeriod,
	CopterDestroyType,
	Float: CopterDestroyDamage,
	Float: CopterDestroyRadius,
	CopterHealthCost,
	CopterHealthType,
	Float: CopterHealthPeriod,
	Float: CopterHealthValue,
	Float: CopterHealthMax,
	CopterRocketCost,
	Float: CopterRocketPeriod,
	Float: CopterRocketDamage,
	Float: CopterRocketRadius,
};

new g_eEntCopter[MAX_PLAYERS+1];
new g_iModeCopter[MAX_PLAYERS+1];
new g_iMenuCopter[MAX_PLAYERS+1];
new g_iSpriteExp, g_iSpriteBeam;
new g_eCopterSetting[eCopterSetting];
new bool: g_bIsCopterUpgradeHealth[MAX_PLAYERS+1];
new bool: g_bIsCopterUpgradeRocket[MAX_PLAYERS+1];

public plugin_init() {
	register_plugin("Copter", "0.2", "Kurtis");

	register_clcmd("copter", "copter_menu");
	register_clcmd("say /copter", "copter_menu");
	register_clcmd("say_team /copter", "copter_menu");

	if(g_eCopterSetting[CopterDestroyType] != 1) {
		RegisterHookChain(RG_CSGameRules_RestartRound, "CSGameRules_RestartRound_Post", 1);
	}

	RegisterHookChain(RG_CSGameRules_PlayerSpawn, "CSGameRules_PlayerSpawn_Post", 1);
	RegisterHookChain(RG_CSGameRules_PlayerKilled, "CSGameRules_PlayerKilled_Post", 1);
	RegisterHookChain(RG_CBasePlayer_PreThink, "CBasePlayer_PreThink", 0);
	RegisterHookChain(RG_CBasePlayer_ResetMaxSpeed, "RG_CBasePlayer_ResetMaxSpeed_Pre", 0);
	RegisterHookChain(RG_CBasePlayer_Jump, "RG_CBasePlayer_Jump_Pre", 0);
	RegisterHookChain(RG_CBasePlayer_Duck, "RG_CBasePlayer_Duck_Pre", 0);
	RegisterHookChain(RG_CBasePlayerWeapon_DefaultDeploy, "CBasePlayerWeapon_DefaultDeploy_Post", 1);

	RegisterHam(Ham_TakeDamage, "info_target", "Ham_TakeDamage_Copter_Pre", 0);
	RegisterHam(Ham_Killed, "info_target", "Ham_Killed_Copter_Pre", 0);

#if defined FULLPACK_ON
	register_forward(FM_AddToFullPack, "Fwd_AddToFullPack_Post", 1);
#endif

	set_task(1.0, "_show_copter_info", .flags = "b");
}

public plugin_precache() {
	load_config();

	precache_model(COPTER_MODEL);
	precache_model(ROCKET_MODEL);

	g_iSpriteExp = precache_model("sprites/dexplo.spr");
	g_iSpriteBeam = precache_model("sprites/zbeam1.spr");

	precache_sound(COPTER_SOUND);
	precache_sound(COPTER_SOUND_LASER);
	precache_sound(COPTER_HEAL);
	precache_sound(COPTER_SOUND_ROCKET_FIRE);
	//precache_sound(COPTER_SOUND_ROCKET_FLY);
}

public client_disconnected(pPlayer) {
	_remove_ent(g_eEntCopter[pPlayer]);

	g_eEntCopter[pPlayer] = NULLENT;
	g_iModeCopter[pPlayer] = Mode_Draw;
}

public copter_menu(pPlayer) {
	if(!is_user_alive(pPlayer)) {
		return;
	}

	new iMenu = menu_create("\yУправление коптером", "copter_menu_handler");
	new iAccount = get_member(pPlayer, m_iAccount);

	if(is_nullent(g_eEntCopter[pPlayer])) {
		menu_additem(iMenu, fmt("\%cКупить коптер \d[\r%i$]^n", iAccount >= g_eCopterSetting[CopterCost] ? 'w' : 'd', g_eCopterSetting[CopterCost]));

		menu_additem(iMenu, "\dРежим: \rбездействие");
		menu_additem(iMenu, "\dРежим: \rатака противников");
		menu_additem(iMenu, "\dРежим: \rручное управление");
		menu_additem(iMenu, "\dРежим: \rкамикадзе");
		menu_additem(iMenu, "\dУлучшить \yкоптер \r(лечение)");
		menu_additem(iMenu, "\dУлучшить \yкоптер \r(атака ракетами)");
	}
	else {
		menu_additem(iMenu, "\wВзорвать коптер^n");

		menu_additem(iMenu, fmt("\%cРежим: \rбездействие", g_iModeCopter[pPlayer] == Mode_Draw ? 'w' : 'd'));
		menu_additem(iMenu, fmt("\%cРежим: \rатака противников", g_iModeCopter[pPlayer] == Mode_Attack ? 'w' : 'd'));
		menu_additem(iMenu, fmt("\%cРежим: \rручное управление", g_iModeCopter[pPlayer] == Mode_Control ? 'w' : 'd'));
		menu_additem(iMenu, fmt("\%cРежим: \rкамикадзе", g_iModeCopter[pPlayer] == Mode_Kamikadze ? 'w' : 'd'));

		if(g_eCopterSetting[CopterHealthCost] == -1 || g_bIsCopterUpgradeHealth[pPlayer]) {
			menu_additem(iMenu, "\dУлучшить \yкоптер \r(лечение)");
		}
		else {
			menu_additem(iMenu, fmt("\%cУлучшить \yкоптер \r(лечение) \d[\y%i$]", iAccount >= g_eCopterSetting[CopterHealthCost] ? 'w' : 'd', g_eCopterSetting[CopterHealthCost]));
		}

		if(g_eCopterSetting[CopterRocketCost] == -1 || g_bIsCopterUpgradeRocket[pPlayer]) {
			menu_additem(iMenu, "\dУлучшить \yкоптер \r(атака ракетами)");
		}
		else {
			menu_additem(iMenu, fmt("\%cУлучшить \yкоптер \r(атака ракетами) \d[\y%i$]", iAccount >= g_eCopterSetting[CopterRocketCost] ? 'w' : 'd', g_eCopterSetting[CopterRocketCost]));
			
		}
	}

	menu_setprop(iMenu, MPROP_EXITNAME, "\wВыход");
	menu_display(pPlayer, iMenu);

	g_iMenuCopter[pPlayer] = iMenu;
}

public copter_menu_handler(pPlayer, iMenu, iItem) {
	menu_destroy(iMenu);

	if(!is_user_alive(pPlayer)) {
		return;
	}

	switch(iItem)
	{
		case MENU_EXIT:{
			return;
		}

		case 0: {
			if(is_nullent(g_eEntCopter[pPlayer])) {
				if(get_member(pPlayer, m_iAccount) >= g_eCopterSetting[CopterCost]) {
					new Float: flVecOrigin[3];
					get_player_origin_front(pPlayer, flVecOrigin, 100.0);
					flVecOrigin[2] += 5.0;

					if(is_hull_vacant(flVecOrigin, HULL_HUMAN, 0)) {
						g_eEntCopter[pPlayer] = rg_create_entity("info_target");

						if(is_nullent(g_eEntCopter[pPlayer])) {
							client_print_color(pPlayer, print_team_default, "Что-то пошло не так, попробуйте позже");

							return;
						}

						rg_add_account(pPlayer, -g_eCopterSetting[CopterCost]);

						engfunc(EngFunc_SetModel, g_eEntCopter[pPlayer], COPTER_MODEL);
						engfunc(EngFunc_SetOrigin, g_eEntCopter[pPlayer], flVecOrigin);
						engfunc(EngFunc_SetSize, g_eEntCopter[pPlayer], Float: {-15.0, -14.0, -4.0}, Float: {10.0, 13.0, 1.0});

						set_entvar(g_eEntCopter[pPlayer], var_classname, "copter");
						set_entvar(g_eEntCopter[pPlayer], var_solid, SOLID_BBOX);
						set_entvar(g_eEntCopter[pPlayer], var_movetype, MOVETYPE_FLY);
						set_entvar(g_eEntCopter[pPlayer], var_euser1, pPlayer);
						set_entvar(g_eEntCopter[pPlayer], var_takedamage, DAMAGE_YES);
						set_entvar(g_eEntCopter[pPlayer], var_health, Float: g_eCopterSetting[CopterHealth]);
						set_entvar(g_eEntCopter[pPlayer], var_gravity, 0.0);
						set_entvar(g_eEntCopter[pPlayer], var_sequence, 1);
						set_entvar(g_eEntCopter[pPlayer], var_animtime, 0.5);
						set_entvar(g_eEntCopter[pPlayer], var_framerate, 30.0);
						set_entvar(g_eEntCopter[pPlayer], var_fuser1, 0.0);
						set_entvar(g_eEntCopter[pPlayer], var_fuser2, 0.0);
						set_entvar(g_eEntCopter[pPlayer], var_impulse, COPTER_IMPULSE);

						g_iModeCopter[pPlayer] = Mode_Draw;
						g_bIsCopterUpgradeHealth[pPlayer] = false;
						g_bIsCopterUpgradeRocket[pPlayer] = false;
					}
					else {
						client_print_color(pPlayer, print_team_default, "Перед вами недостаточно места для создания коптера");
					}
				}
				else {
					client_print_color(pPlayer, print_team_default, "У вас не хватает ^4денег ^1для покупки ^3коптера");
					return;
				}
			}
			else {
				if(g_iModeCopter[pPlayer] == Mode_Control) {
					g_iModeCopter[pPlayer] = Mode_Draw;
					set_entvar(g_eEntCopter[pPlayer], var_movetype, MOVETYPE_TOSS);
					set_entvar(g_eEntCopter[pPlayer], var_velocity, NULL_VECTOR);

					rg_reset_maxspeed(pPlayer);
					engset_view(pPlayer, pPlayer);

					new iActiveItem = get_member(pPlayer, m_pActiveItem);

					if(!is_nullent(iActiveItem)) {
						ExecuteHamB(Ham_Item_Deploy, iActiveItem);
					}
				}

				if(!is_nullent(g_eEntCopter[pPlayer])) {
					_copter_explode(g_eEntCopter[pPlayer]);
				}

				_remove_ent(g_eEntCopter[pPlayer]);
				g_eEntCopter[pPlayer] = NULLENT;
				client_print_color(pPlayer, print_team_default, "Вы взорвали свой ^3коптер");

				return;
			}
		}

		case 1: {
			if(!is_nullent(g_eEntCopter[pPlayer])) {
				if(g_iModeCopter[pPlayer] == Mode_Control) {
					g_iModeCopter[pPlayer] = Mode_Draw;
					set_entvar(g_eEntCopter[pPlayer], var_movetype, MOVETYPE_FLY);
					set_entvar(g_eEntCopter[pPlayer], var_velocity, NULL_VECTOR);

					rg_reset_maxspeed(pPlayer);
					engset_view(pPlayer, pPlayer);

					new iActiveItem = get_member(pPlayer, m_pActiveItem);

					if(!is_nullent(iActiveItem)) {
						ExecuteHamB(Ham_Item_Deploy, iActiveItem);
					}
				}
				else {
					g_iModeCopter[pPlayer] = Mode_Draw;
					set_entvar(g_eEntCopter[pPlayer], var_velocity, NULL_VECTOR);
				}
			}
		}

		case 2: {
			if(!is_nullent(g_eEntCopter[pPlayer])) {
				if(g_iModeCopter[pPlayer] == Mode_Control) {
					g_iModeCopter[pPlayer] = Mode_Attack;
					set_entvar(g_eEntCopter[pPlayer], var_movetype, MOVETYPE_FLY);
					set_entvar(g_eEntCopter[pPlayer], var_velocity, NULL_VECTOR);

					rg_reset_maxspeed(pPlayer);
					engset_view(pPlayer, pPlayer);

					new iActiveItem = get_member(pPlayer, m_pActiveItem);

					if(!is_nullent(iActiveItem)) {
						ExecuteHamB(Ham_Item_Deploy, iActiveItem);
					}
				}
				else {
					g_iModeCopter[pPlayer] = Mode_Attack;
					set_entvar(g_eEntCopter[pPlayer], var_velocity, NULL_VECTOR);
				}
			}
		}

		case 3: {
			if(!is_nullent(g_eEntCopter[pPlayer])) {
				if(g_iModeCopter[pPlayer] != Mode_Control) {
					g_iModeCopter[pPlayer] = Mode_Control;
					set_entvar(g_eEntCopter[pPlayer], var_movetype, MOVETYPE_TOSS);
					set_entvar(g_eEntCopter[pPlayer], var_velocity, NULL_VECTOR);

					set_entvar(pPlayer, var_maxspeed, -1.0);
					engset_view(pPlayer, g_eEntCopter[pPlayer]);

					new iActiveItem = get_member(pPlayer, m_pActiveItem);

					if(!is_nullent(iActiveItem)) {
						ExecuteHamB(Ham_Item_Deploy, iActiveItem);
					}
				}
			}
		}

		case 4: {
			if(!is_nullent(g_eEntCopter[pPlayer])) {
				if(g_iModeCopter[pPlayer] == Mode_Control) {
					g_iModeCopter[pPlayer] = Mode_Kamikadze;
					set_entvar(g_eEntCopter[pPlayer], var_movetype, MOVETYPE_TOSS);
					set_entvar(g_eEntCopter[pPlayer], var_velocity, NULL_VECTOR);

					rg_reset_maxspeed(pPlayer);
					engset_view(pPlayer, pPlayer);

					new iActiveItem = get_member(pPlayer, m_pActiveItem);

					if(!is_nullent(iActiveItem)) {
						ExecuteHamB(Ham_Item_Deploy, iActiveItem);
					}
				}
				else {
					g_iModeCopter[pPlayer] = Mode_Kamikadze;
					set_entvar(g_eEntCopter[pPlayer], var_velocity, NULL_VECTOR);
				}
			}
		}

		case 5: {
			if(g_eCopterSetting[CopterHealthCost] == -1) {
				client_print_color(pPlayer, print_team_default, "^1В данный момент ^4функция лечения ^3отключена");
			}
			else if(!is_nullent(g_eEntCopter[pPlayer]) && !g_bIsCopterUpgradeHealth[pPlayer]) {
				if(get_member(pPlayer, m_iAccount) >= g_eCopterSetting[CopterHealthCost]) {
					rg_add_account(pPlayer, g_eCopterSetting[CopterHealthCost]);
					g_bIsCopterUpgradeHealth[pPlayer] = true;

					client_print_color(pPlayer, print_team_default, "^4Коптер ^1улучшен. Доступно ^4лечение");
				}
			}
		}

		case 6: {
			if(g_eCopterSetting[CopterRocketCost] == -1) {
				client_print_color(pPlayer, print_team_default, "^1В данный момент ^4функция ракет ^3отключена");
			}
			else if(!is_nullent(g_eEntCopter[pPlayer]) && !g_bIsCopterUpgradeRocket[pPlayer]) {
				if(get_member(pPlayer, m_iAccount) >= g_eCopterSetting[CopterRocketCost]) {
					rg_add_account(pPlayer, g_eCopterSetting[CopterRocketCost]);
					g_bIsCopterUpgradeRocket[pPlayer] = true;

					client_print_color(pPlayer, print_team_default, "^4Коптер ^1улучшен. Доступны ^4ракеты ^3(ПКМ)");
				}
			}
		}
	}

	RequestFrame("copter_menu", pPlayer);
}

public CSGameRules_RestartRound_Post() {
	for(new pPlayer = 1; pPlayer <= MaxClients; pPlayer++) {
		if(!is_user_connected(pPlayer))
			continue;

		_remove_ent(g_eEntCopter[pPlayer]);

		g_eEntCopter[pPlayer] = NULLENT;
		g_iModeCopter[pPlayer] = Mode_Draw;
	}
}

public CSGameRules_PlayerSpawn_Post(pPlayer) {
	if(!is_user_alive(pPlayer)) {
		return;
	}

	if(g_iModeCopter[pPlayer] == Mode_Control) {
		engset_view(pPlayer, pPlayer);
	}
	g_iModeCopter[pPlayer] = Mode_Draw;

	if(g_eCopterSetting[CopterDestroyType] != 1) {
		_remove_ent(g_eEntCopter[pPlayer]);
		g_eEntCopter[pPlayer] = NULLENT;
	}

	player_close_menu_copter(pPlayer);
}

public CSGameRules_PlayerKilled_Post(pVictim, pKiller, iInflictor) {
	if(!is_user_connected(pVictim)) {
		return;
	}

	if(g_iModeCopter[pVictim] == Mode_Draw) {
		engset_view(pVictim, pVictim);
	}

	if(g_eCopterSetting[CopterDestroyType] == 1 || g_eCopterSetting[CopterDestroyType] == 3) {
		_remove_ent(g_eEntCopter[pVictim]);
		
		g_eEntCopter[pVictim] = NULLENT;
		g_iModeCopter[pVictim] = Mode_Draw;
	}

	player_close_menu_copter(pVictim);
}

public CBasePlayer_PreThink(pPlayer) {
	if(!is_user_alive(pPlayer) || is_nullent(g_eEntCopter[pPlayer])) {
		return;
	}

	static Float: flGameTime; flGameTime = get_gametime();
	static Float: flNextAmbient[MAX_PLAYERS+1];

	if(flNextAmbient[pPlayer] < flGameTime) {
		flNextAmbient[pPlayer] = flGameTime + 2.0;
		rh_emit_sound2(g_eEntCopter[pPlayer], 0, CHAN_STATIC, COPTER_SOUND, VOL_NORM, ATTN_NORM, 0, PITCH_NORM, SND_EMIT2_NOPAS, Float: {0.0, 0.0, 0.0});
	}

	if(g_bIsCopterUpgradeHealth[pPlayer]) {
		static Float: flNextTimeHealth[MAX_PLAYERS+1];

		if(flNextTimeHealth[pPlayer] < flGameTime) {
			flNextTimeHealth[pPlayer] = flGameTime + 0.1;

			switch(g_eCopterSetting[CopterHealthType]) {
				case 1: {
					new Float: flVecOriginCopter[3], Float: flVecOriginPlayer[3];

					get_entvar(g_eEntCopter[pPlayer], var_origin, flVecOriginCopter);
					get_entvar(pPlayer, var_origin, flVecOriginPlayer);

					engfunc(EngFunc_TraceLine, flVecOriginCopter, flVecOriginPlayer, DONT_IGNORE_MONSTERS, g_eEntCopter[pPlayer], 0);

					if(get_tr2(0, TR_pHit) == pPlayer) {
						static Float: flNextTimeHeal[MAX_PLAYERS+1];

						if(flNextTimeHeal[pPlayer] < flGameTime) {
							flNextTimeHeal[pPlayer] = flGameTime + Float: g_eCopterSetting[CopterHealthPeriod];

							new Float: flHealthUser = Float: get_entvar(pPlayer, var_health);

							if(flHealthUser < Float: g_eCopterSetting[CopterHealthMax]) {
								set_entvar(pPlayer, var_health, floatclamp(flHealthUser + Float: g_eCopterSetting[CopterHealthValue], 1.0, Float: g_eCopterSetting[CopterHealthMax]));

								CREATE_BEAMPOINTS(flVecOriginCopter, flVecOriginPlayer, g_iSpriteBeam, 0, 0, 1, 5, 5, 0, 255, 0, 255, 0);
								rh_emit_sound2(g_eEntCopter[pPlayer], 0, CHAN_STATIC, COPTER_HEAL, VOL_NORM, ATTN_NORM, 0, PITCH_NORM, SND_EMIT2_NOPAS, Float: {0.0, 0.0, 0.0});
							}
						}
					}
				}

				case 2: {
					static Float: flNextTimeHeal[MAX_PLAYERS+1];

					if(flNextTimeHeal[pPlayer] < flGameTime) {
						flNextTimeHeal[pPlayer] = flGameTime + Float: g_eCopterSetting[CopterHealthPeriod];
						new Float: flVecOriginPlayer[3], Float: flVecOriginCopter[3];
						new iPlayers[MAX_PLAYERS], iCount;

						switch(get_member(pPlayer, m_iTeam)) {
							case TEAM_TERRORIST: {
								get_players_ex(iPlayers, iCount,
									GetPlayers_ExcludeDead | GetPlayers_MatchTeam | GetPlayers_ExcludeHLTV | GetPlayers_IncludeConnecting,
									"TERRORIST"
								);
							}
							case TEAM_CT: {
								get_players_ex(iPlayers, iCount,
									GetPlayers_ExcludeDead | GetPlayers_MatchTeam | GetPlayers_ExcludeHLTV | GetPlayers_IncludeConnecting,
									"CT"
								);
							}
						}
	
						get_entvar(g_eEntCopter[pPlayer], var_origin, flVecOriginCopter);
	
						new bool: bIsOneMatch;
	
						for(new i, id, Float: flHealthUser; i < iCount; i++) {
							id = iPlayers[i];
	
							get_entvar(id, var_origin, flVecOriginPlayer);
							engfunc(EngFunc_TraceLine, flVecOriginCopter, flVecOriginPlayer, DONT_IGNORE_MONSTERS, g_eEntCopter[pPlayer], 0);
	
							if(get_tr2(0, TR_pHit) == id) {
								flHealthUser = Float: get_entvar(id, var_health);
	
								if(flHealthUser < Float: g_eCopterSetting[CopterHealthMax]) {
									set_entvar(id, var_health, floatclamp(flHealthUser + Float: g_eCopterSetting[CopterHealthValue], 1.0, Float: g_eCopterSetting[CopterHealthMax]));
	
									CREATE_BEAMPOINTS(flVecOriginCopter, flVecOriginPlayer, g_iSpriteBeam, 0, 0, 1, 5, 5, 0, 255, 0, 255, 0);
									bIsOneMatch = true;
								}
							}
						}
	
						if(bIsOneMatch) {
							rh_emit_sound2(g_eEntCopter[pPlayer], 0, CHAN_STATIC, COPTER_HEAL, VOL_NORM, ATTN_NORM, 0, PITCH_NORM, SND_EMIT2_NOPAS, Float: {0.0, 0.0, 0.0});
						}
					}
				}
			}
		}
	}

	switch(g_iModeCopter[pPlayer]) {
		case Mode_Attack: {
			if(get_entvar(g_eEntCopter[pPlayer], var_fuser1) < flGameTime) {
				set_entvar(g_eEntCopter[pPlayer], var_fuser1, flGameTime + g_eCopterSetting[CopterDamagePeriod]);

				new pVictim = find_range_enemy(pPlayer, g_eEntCopter[pPlayer]);

				if(pVictim == NULLENT) {
					return;
				}

				new Float: flVecOriginVictim[3];
				get_entvar(pVictim, var_origin, flVecOriginVictim);
				flVecOriginVictim[2] += random_float(-10.0, 10.0);

				CREATE_BEAMENTPOINT(g_eEntCopter[pPlayer], flVecOriginVictim, g_iSpriteBeam, 0, 0, 1, 1, 1, 255, 255, 72, 255, 0);
				ExecuteHamB(Ham_TakeDamage, pVictim, g_eEntCopter[pPlayer], pPlayer, Float: g_eCopterSetting[CopterDamage], DMG_ENERGYBEAM);
				rh_emit_sound2(g_eEntCopter[pPlayer], 0, CHAN_STATIC, COPTER_SOUND_LASER, VOL_NORM, ATTN_NORM, 0, PITCH_NORM, SND_EMIT2_NOPAS, Float: {0.0, 0.0, 0.0});
			}

			if(g_bIsCopterUpgradeRocket[pPlayer] && get_entvar(g_eEntCopter[pPlayer], var_fuser2) < flGameTime) {
				set_entvar(g_eEntCopter[pPlayer], var_fuser2, flGameTime + Float: g_eCopterSetting[CopterRocketPeriod]);

				new pVictim = find_range_enemy(pPlayer, g_eEntCopter[pPlayer]);

				if(pVictim == NULLENT) {
					return;
				}

				new Float: flVecOriginVictim[3];
				get_entvar(pVictim, var_origin, flVecOriginVictim);

				new Float: flVecOriginCopter[3];
				get_entvar(g_eEntCopter[pPlayer], var_origin, flVecOriginCopter);
				_create_rocket(pPlayer, flVecOriginCopter, flVecOriginVictim);
			}
		}

		case Mode_Control: {
			new iButton = get_entvar(pPlayer, var_button);

			new Float: flVecVelocity[3], Float: flVecAngles[3];
			get_entvar(pPlayer, var_angles, flVecAngles);

			if(iButton & IN_FORWARD) {
				velocity_by_aim(pPlayer, 240, flVecVelocity);
				flVecVelocity[2] *= -1.0;
			}
			else if(iButton & IN_BACK) {
				velocity_by_aim(pPlayer, -240, flVecVelocity);
				flVecVelocity[2] *= -1.0;
			}

			set_entvar(g_eEntCopter[pPlayer], var_angles, flVecAngles);
			set_entvar(g_eEntCopter[pPlayer], var_velocity, flVecVelocity);

			set_entvar(pPlayer, var_sequence, 13);
			set_entvar(pPlayer, var_gaitsequence, 0);
			set_entvar(pPlayer, var_velocity, NULL_VECTOR);

			if(iButton & IN_ATTACK) {
				if(get_entvar(g_eEntCopter[pPlayer], var_fuser1) < flGameTime) {
					set_entvar(g_eEntCopter[pPlayer], var_fuser1, flGameTime + g_eCopterSetting[CopterDamagePeriod]);

					new Float: flVecOriginEnd[3];
					new pVictim = get_origin_aiming_ent(g_eEntCopter[pPlayer], flVecOriginEnd);

					if(is_user_alive(pVictim)) {
						new Float: flVecOriginVictim[3];
						get_entvar(pVictim, var_origin, flVecOriginVictim);

						if(get_member(pPlayer, m_iTeam) != get_member(pVictim, m_iTeam)) {
							flVecOriginVictim[2] += random_float(-10.0, 10.0);

							ExecuteHamB(Ham_TakeDamage, pVictim, g_eEntCopter[pPlayer], pPlayer, Float: g_eCopterSetting[CopterDamage], DMG_ENERGYBEAM);
						}

						CREATE_BEAMENTPOINT(g_eEntCopter[pPlayer], flVecOriginVictim, g_iSpriteBeam, 0, 0, 1, 1, 1, 255, 255, 72, 255, 0);
						rh_emit_sound2(g_eEntCopter[pPlayer], 0, CHAN_STATIC, COPTER_SOUND_LASER, VOL_NORM, ATTN_NORM, 0, PITCH_NORM, SND_EMIT2_NOPAS, Float: {0.0, 0.0, 0.0});
					}
					else {
						new Float: flVecOriginStart[3];
						get_entvar(g_eEntCopter[pPlayer], var_origin, flVecOriginStart);
	
						CREATE_BEAMPOINTS(flVecOriginStart, flVecOriginEnd, g_iSpriteBeam, 0, 0, 1, 1, 1, 255, 255, 72, 255, 0);
						rh_emit_sound2(g_eEntCopter[pPlayer], 0, CHAN_STATIC, COPTER_SOUND_LASER, VOL_NORM, ATTN_NORM, 0, PITCH_NORM, SND_EMIT2_NOPAS, Float: {0.0, 0.0, 0.0});
					}
				}
			}
			else if(iButton & IN_ATTACK2) {
				if(g_bIsCopterUpgradeRocket[pPlayer] && get_entvar(g_eEntCopter[pPlayer], var_fuser2) < flGameTime) {
					set_entvar(g_eEntCopter[pPlayer], var_fuser2, flGameTime + Float: g_eCopterSetting[CopterRocketPeriod]);
			
					new Float: flVecOriginVictim[3];
					get_origin_aiming_ent(g_eEntCopter[pPlayer], flVecOriginVictim);

					new Float: flVecOriginCopter[3];
					get_entvar(g_eEntCopter[pPlayer], var_origin, flVecOriginCopter);

					_create_rocket(pPlayer, flVecOriginCopter, flVecOriginVictim);
				}
			}
		}

		case Mode_Kamikadze:
		{
			static Float: flNextTimeKamikadze[MAX_PLAYERS+1];
			if(flNextTimeKamikadze[pPlayer] < flGameTime) {
				flNextTimeKamikadze[pPlayer]  = flGameTime + 0.1;

				new pVictim = find_range_enemy(pPlayer, g_eEntCopter[pPlayer]);

				if(pVictim == NULLENT) {
					return;
				}

				new Float: flVecOriginStart[3], Float: flVecOriginEnd[3], Float: flVecVelocity[3], Float: flDist;
				get_entvar(g_eEntCopter[pPlayer], var_origin, flVecOriginStart);
				get_entvar(pVictim, var_origin, flVecOriginEnd);

				flDist = get_distance_f(flVecOriginStart, flVecOriginEnd);

				if(flDist < 50.0) {
					_copter_explode(g_eEntCopter[pPlayer]);
					_remove_ent(g_eEntCopter[pPlayer]);
					g_eEntCopter[pPlayer] = NULLENT;

					player_close_menu_copter(pPlayer);
					return;
				}

				xs_vec_sub(flVecOriginEnd, flVecOriginStart, flVecVelocity);

				if(flDist < 200.0) {
					xs_vec_mul_scalar(flVecVelocity, 2.0, flVecVelocity);
				}

				set_entvar(g_eEntCopter[pPlayer], var_velocity, flVecVelocity);
			}
		}
	}
}

public RG_CBasePlayer_ResetMaxSpeed_Pre(pPlayer) {
	if(!is_user_connected(pPlayer) && g_iModeCopter[pPlayer] == Mode_Control) {
		set_entvar(pPlayer, var_maxspeed, -1.0);
		return HC_SUPERCEDE;
	}

	return HC_CONTINUE;
}

public RG_CBasePlayer_Jump_Pre(pPlayer) {
	if(!is_user_alive(pPlayer) || g_iModeCopter[pPlayer] != Mode_Control || is_nullent(g_eEntCopter[pPlayer])) {
		return;
	}

	new Float: flVecVelocity[3];
	get_entvar(g_eEntCopter[pPlayer], var_velocity, flVecVelocity);
	flVecVelocity[2] += 100.0;
	set_entvar(g_eEntCopter[pPlayer], var_velocity, flVecVelocity);

	set_entvar(pPlayer, var_oldbuttons, get_entvar(pPlayer, var_oldbuttons) | IN_JUMP);
}

public RG_CBasePlayer_Duck_Pre(pPlayer) {
	if(!is_user_alive(pPlayer) || g_iModeCopter[pPlayer] != Mode_Control || is_nullent(g_eEntCopter[pPlayer])) {
		return;
	}

	new Float: flVecVelocity[3];
	get_entvar(g_eEntCopter[pPlayer], var_velocity, flVecVelocity);
	flVecVelocity[2] -= 100.0;
	set_entvar(g_eEntCopter[pPlayer], var_velocity, flVecVelocity);

	set_entvar(pPlayer, var_oldbuttons, get_entvar(pPlayer, var_oldbuttons) | IN_DUCK);
}

public CBasePlayerWeapon_DefaultDeploy_Post(iItem, const szViewModel[], const szWeaponModel[], iAnim, const szAnimExt[], skiplocal)
{
	if(is_nullent(iItem)) {
		return;
	}

	new pPlayer = get_member(iItem, m_pPlayer);

	if(!is_user_alive(pPlayer) || g_iModeCopter[pPlayer] != Mode_Control) {
		return;
	}

	set_member(pPlayer, m_flNextAttack, get_gametime());
}

public Ham_TakeDamage_Copter_Pre(eEnt, iInflictor, pAttacker, Float: flDamage, bitDamageType) {
	if(is_nullent(eEnt) || get_entvar(eEnt, var_impulse) != COPTER_IMPULSE) {
		return;
	}

	if(!is_user_connected(pAttacker)) {
		return;
	}

	new pOwner = get_entvar(eEnt, var_euser1);

	if(pOwner == pAttacker || !is_user_connected(pOwner) || get_member(pAttacker, m_iTeam) != get_member(pOwner, m_iTeam)) {
		return;
	}

	SetHamParamFloat(4, 0.0);
}

public Ham_Killed_Copter_Pre(eEnt, pAttacker, iCorpse) {
	if(is_nullent(eEnt) || get_entvar(eEnt, var_impulse) != COPTER_IMPULSE) {
		return HAM_IGNORED;
	}

	_copter_explode(eEnt);
	_remove_ent(eEnt);

	new pOwner = get_entvar(eEnt, var_euser1);

	if(is_user_connected(pOwner)) {
		g_eEntCopter[pOwner] = NULLENT;

		if(is_user_alive(pOwner) && g_iModeCopter[pOwner] == Mode_Control) {
			engset_view(pOwner, pOwner);
		}

		player_close_menu_copter(pOwner);

		g_eEntCopter[pOwner] = NULLENT;
		g_iModeCopter[pOwner] = Mode_Draw;

		if(pOwner == pAttacker) {
			client_print_color(pOwner, print_team_default, "Вы взорвали свой ^3коптер");
		}
		else if(is_user_connected(pAttacker)) {
			client_print_color(pOwner, print_team_default, "Ваш^3 коптер ^1уничтожил^4 %n", pAttacker);
		}
		else {
			client_print_color(pOwner, print_team_default, "Ваш^3 коптер ^1уничтожен");
		}
	}

	return HAM_SUPERCEDE;
}

public load_config() {
	new const szConfigPath[] = "addons/amxmodx/configs/copter_settings.cfg";

	if(!file_exists(szConfigPath)) {
		set_fail_state("Конфиг ^"%s^" не загружен. Плагин остановлен", szConfigPath);
		return;
	}

	new INIParser: iParser = INI_CreateParser();

	INI_SetReaders(iParser, "INI_ReadKeyValue");
	INI_ParseFile(iParser, szConfigPath);

	INI_DestroyParser(iParser);
}

public bool: INI_ReadKeyValue(INIParser: iParser, const szKey[], const szValue[]) {
	if(szKey[0] == EOS) {
		return true;
	}

	new szString[128];
	format(szString, charsmax(szString), "%s", szValue);
	trim(szString);

	if(equal(szKey, "copter_cost")) {
		g_eCopterSetting[CopterCost] = str_to_num(szString);
	}
	else if(equal(szKey, "copter_health")) {
		g_eCopterSetting[CopterHealth] = str_to_float(szString);
	}
	else if(equal(szKey, "copter_damage")) {
		g_eCopterSetting[CopterDamage] = str_to_float(szString);
	}
	else if(equal(szKey, "copter_period_damage")) {
		g_eCopterSetting[CopterDamagePeriod] = str_to_float(szString);
	}
	else if(equal(szKey, "copter_destroy_type")) {
		g_eCopterSetting[CopterDestroyType] = str_to_num(szString);
	}
	else if(equal(szKey, "copter_destroy_damage")) {
		g_eCopterSetting[CopterDestroyDamage] = str_to_float(szString);
	}
	else if(equal(szKey, "copter_destroy_radius")) {
		g_eCopterSetting[CopterDestroyRadius] = str_to_float(szString);
	}
	else if(equal(szKey, "copter_up_health_cost")) {
		g_eCopterSetting[CopterHealthCost] = str_to_num(szString);
	}
	else if(equal(szKey, "copter_health_type")) {
		g_eCopterSetting[CopterHealthType] = str_to_num(szString);
	}
	else if(equal(szKey, "copter_health_period")) {
		g_eCopterSetting[CopterHealthPeriod] = str_to_float(szString);
	}
	else if(equal(szKey, "copter_health_value")) {
		g_eCopterSetting[CopterHealthValue] = str_to_float(szString);
	}
	else if(equal(szKey, "copter_health_max")) {
		g_eCopterSetting[CopterHealthMax] = str_to_float(szString);
	}
	else if(equal(szKey, "copter_up_rocket_cost")) {
		g_eCopterSetting[CopterRocketCost] = str_to_num(szString);
	}
	else if(equal(szKey, "copter_rocket_period_damage")) {
		g_eCopterSetting[CopterRocketPeriod] = str_to_float(szString);
	}
	else if(equal(szKey, "copter_rocket_damage")) {
		g_eCopterSetting[CopterRocketDamage] = Float: str_to_float(szString);
	}
	else if(equal(szKey, "copter_rocket_exp_radius")) {
		g_eCopterSetting[CopterRocketRadius] = Float: str_to_float(szString);
	}

	return true;
}

#if defined FULLPACK_ON
public Fwd_AddToFullPack_Post(es, e, ent, host, flags, player, pSet)
{
	if(!player || !is_user_connected(e) || g_iModeCopter[e] != Mode_Control)
		return;

	set_es(es, ES_Sequence, 62); // ref_aim_c4
	set_es(es, ES_GaitSequence, 14); // ref_shoot_carbine
	set_es(es, ES_WeaponModel, NULL_STRING);
	set_es(es, ES_Angles, NULL_VECTOR);
}
#endif

public _remove_ent(eEnt) {
	if(!is_nullent(eEnt)) {
		rg_remove_entity(eEnt);
	}
}

public _copter_explode(eEnt) {
	new Float: flVecOriginStart[3], Float: flVecOriginEnd[3];
	get_entvar(eEnt, var_origin, flVecOriginStart);

	message_begin_f(MSG_BROADCAST, SVC_TEMPENTITY);
	write_byte(TE_EXPLOSION);
	write_coord_f(flVecOriginStart[0]);
	write_coord_f(flVecOriginStart[1]);
	write_coord_f(flVecOriginStart[2]);
	write_short(g_iSpriteExp);
	write_byte(floatround(Float: g_eCopterSetting[CopterDestroyRadius] / 10.0)); // scale
	write_byte(40); // framerate
	write_byte(TE_EXPLFLAG_NONE);
	message_end(); 

	new pOwner = get_entvar(eEnt, var_euser1);

	if(!is_user_alive(pOwner)) {
		return;
	}

	new iPlayers[MAX_PLAYERS], iCount;

	switch(get_member(pOwner, m_iTeam)) {
		case TEAM_TERRORIST: {
			get_players_ex(iPlayers, iCount,
				GetPlayers_ExcludeDead | GetPlayers_MatchTeam | GetPlayers_ExcludeHLTV | GetPlayers_IncludeConnecting,
				"CT"
			);
		}
		case TEAM_CT: {
			get_players_ex(iPlayers, iCount,
				GetPlayers_ExcludeDead | GetPlayers_MatchTeam | GetPlayers_ExcludeHLTV | GetPlayers_IncludeConnecting,
				"TERRORIST"
			);
		}
		default: {
			return;
		}
	}

	for(new i, id; i < iCount; i++) {
		id = iPlayers[i];

		get_entvar(id, var_origin, flVecOriginEnd);

		if(get_distance_f(flVecOriginStart, flVecOriginEnd) < Float: g_eCopterSetting[CopterDestroyRadius]) {
			ExecuteHamB(Ham_TakeDamage, id, eEnt, pOwner, Float: g_eCopterSetting[CopterDestroyDamage], DMG_BURN);
		}
	}
}

public _remove_rocket(eEnt) {
	if(!is_nullent(eEnt)) {
		SetThink(eEnt, "");
		SetTouch(eEnt, "");

		set_entvar(eEnt, var_nextthink, get_gametime());
		rg_remove_entity(eEnt);
	}
}

public _create_rocket(pPlayer, Float: flVecOriginStart[3], Float: flVecOriginEnd[3]) {
	new eEnt = rg_create_entity("info_target");

	if(!is_nullent(eEnt)) {
		engfunc(EngFunc_SetModel, eEnt, ROCKET_MODEL);
		engfunc(EngFunc_SetOrigin, eEnt, flVecOriginStart);
		engfunc(EngFunc_SetSize, eEnt, Float: {-10.0, -10.0, -5.0}, Float: {10.0, 10.0, 5.0});

		set_entvar(eEnt, var_classname, "rocket");
		set_entvar(eEnt, var_solid, SOLID_TRIGGER);
		set_entvar(eEnt, var_movetype, MOVETYPE_FLY);
		set_entvar(eEnt, var_owner, g_eEntCopter[pPlayer]);
		set_entvar(eEnt, var_euser1, pPlayer);
		set_entvar(eEnt, var_nextthink, get_gametime() + 20.0);

		rh_emit_sound2(g_eEntCopter[pPlayer], 0, CHAN_STATIC, COPTER_SOUND_ROCKET_FIRE, VOL_NORM, ATTN_NORM, 0, PITCH_NORM, SND_EMIT2_NOPAS, Float: {0.0, 0.0, 0.0});
		//rh_emit_sound2(g_eEntCopter[pPlayer], 0, CHAN_STATIC, COPTER_SOUND_ROCKET_FLY, VOL_NORM, ATTN_NORM, 0, PITCH_NORM, SND_EMIT2_NOPAS, Float: {0.0, 0.0, 0.0});

		new Float: flVecVelocity[3];
		//xs_vec_sub_scaled(flVecOriginEnd, flVecOriginStart, 500.0, flVecVelocity);
		xs_vec_sub(flVecOriginEnd, flVecOriginStart, flVecVelocity);
		set_entvar(eEnt, var_velocity, flVecVelocity);

		SetThink(eEnt, "_remove_rocket");
		SetTouch(eEnt, "_explode_rocket");

		CREATE_BEAMFOLLOW(eEnt, g_iSpriteBeam, 10, 10, 255, 255, 255, 255, 0);
	}
}

public _explode_rocket(eEnt, eOther) {
	if(is_nullent(eEnt) || get_entvar(eEnt, var_owner) == eOther) {
		return;
	}
	
	new Float: flVecOriginStart[3], Float: flVecOriginEnd[3];
	get_entvar(eEnt, var_origin, flVecOriginStart);

	message_begin_f(MSG_BROADCAST, SVC_TEMPENTITY);
	write_byte(TE_EXPLOSION);
	write_coord_f(flVecOriginStart[0]);
	write_coord_f(flVecOriginStart[1]);
	write_coord_f(flVecOriginStart[2]);
	write_short(g_iSpriteExp);
	write_byte(floatround(Float: g_eCopterSetting[CopterRocketRadius] / 10.0)); // scale
	write_byte(40); // framerate
	write_byte(TE_EXPLFLAG_NONE);
	message_end(); 

	_remove_rocket(eEnt);

	new pOwner = get_entvar(eEnt, var_euser1);

	if(!is_user_alive(pOwner)) {
		return;
	}

	new iPlayers[MAX_PLAYERS], iCount;

	switch(get_member(pOwner, m_iTeam)) {
		case TEAM_TERRORIST: {
			get_players_ex(iPlayers, iCount,
				GetPlayers_ExcludeDead | GetPlayers_MatchTeam | GetPlayers_ExcludeHLTV | GetPlayers_IncludeConnecting,
				"CT"
			);
		}
		case TEAM_CT: {
			get_players_ex(iPlayers, iCount,
				GetPlayers_ExcludeDead | GetPlayers_MatchTeam | GetPlayers_ExcludeHLTV | GetPlayers_IncludeConnecting,
				"TERRORIST"
			);
		}
		default: {
			return;
		}
	}

	for(new i, id; i < iCount; i++) {
		id = iPlayers[i];

		get_entvar(id, var_origin, flVecOriginEnd);

		if(get_distance_f(flVecOriginStart, flVecOriginEnd) < Float: g_eCopterSetting[CopterRocketRadius]) {
			ExecuteHamB(Ham_TakeDamage, id, eEnt, pOwner, Float: g_eCopterSetting[CopterRocketDamage], DMG_BURN);
		}
	}
}

public player_close_menu_copter(pPlayer) {
	new iIndexMenu, iIndexMenuNew;
	if(player_menu_info(pPlayer, iIndexMenu, iIndexMenuNew)) {
		if(g_iMenuCopter[pPlayer] == iIndexMenuNew) {
			menu_cancel(pPlayer);
			show_menu(pPlayer, 0, "^n", 1);
		}
	}
}

public _show_copter_info() {
	new iPlayers[MAX_PLAYERS], iCount;

	get_players_ex(iPlayers, iCount,
		GetPlayers_ExcludeDead | GetPlayers_MatchTeam | GetPlayers_ExcludeHLTV | GetPlayers_IncludeConnecting | GetPlayers_ExcludeBots,
			"CT"
	);

	static szHudInfo1[128], szHudInfo2[128];

	for(new i, id, eEnt, Float: flReload, Float: flGameTime = get_gametime(); i < iCount; i++) {
		id = iPlayers[i];
		eEnt = get_ent_aiming(id);

		if(!is_nullent(eEnt) && get_entvar(eEnt, var_impulse) == COPTER_IMPULSE && g_iModeCopter[id] != Mode_Control) {
			set_dhudmessage(0, 255, 0, -1.0, 0.35, .holdtime = 0.9);
			show_dhudmessage(id, "Коптер^nВладелец: %n^nЗдоровье: %..1f", get_entvar(eEnt, var_euser1), Float: get_entvar(eEnt, var_health));
		}

		if(!is_nullent(g_eEntCopter[id]) && g_iModeCopter[id] == Mode_Control) {
			flReload = get_entvar(g_eEntCopter[id], var_fuser1);

			if(flGameTime < flReload) {
				format(szHudInfo1, charsmax(szHudInfo1), "Лазер: %..1f сек", flReload - flGameTime);
			}
			else {
				format(szHudInfo1, charsmax(szHudInfo1), "Стрельба: ЛКМ");
			}

			if(g_bIsCopterUpgradeRocket[id]) {
				flReload = get_entvar(g_eEntCopter[id], var_fuser2);
		
				if(flGameTime < flReload) {
					format(szHudInfo2, charsmax(szHudInfo2), "Ракета: %..1f сек", flReload - flGameTime);
				}
				else {
					format(szHudInfo2, charsmax(szHudInfo2), "Стрельба: ПКМ");
				}
			}
			else {
				format(szHudInfo2, charsmax(szHudInfo2), "Ракета: недоступно");
			}

			set_dhudmessage(255, 255, 255, -1.0, 0.15, .holdtime = 0.9);
			show_dhudmessage(id, "%s^n%s", szHudInfo1, szHudInfo2);
		}
	}
}

// thx Retro-kolt Lincoln
stock CREATE_BEAMENTPOINT(iEntity, Float: flVecOrigin[3], pSprite, iStartFrame = 0, iFrameRate = 0, iLife, iWidth, iAmplitude = 0, iRed, iGreen, iBlue, iBrightness, iScrollSpeed = 0, iReliable = 0)
{
	message_begin(iReliable ? MSG_ALL : MSG_BROADCAST, SVC_TEMPENTITY);
	write_byte(TE_BEAMENTPOINT);
	write_short(iEntity);
	write_coord_f(flVecOrigin[0]);
	write_coord_f(flVecOrigin[1]);
	write_coord_f(flVecOrigin[2]);
	write_short(pSprite); // Индекс спрайта из прекеша (index of precached sprite)
	write_byte(iStartFrame);
	write_byte(iFrameRate); // 0.1's
	write_byte(iLife); // 0.1's
	write_byte(iWidth);
	write_byte(iAmplitude); // 0.01's
	write_byte(iRed);
	write_byte(iGreen);
	write_byte(iBlue);
	write_byte(iBrightness);
	write_byte(iScrollSpeed); // 0.1's
	message_end();
}

stock CREATE_BEAMPOINTS(Float:fStartOrigin[3], Float:fEndOrigin[3], pSprite, iStartFrame = 0, iFrameRate = 0, iLife, iWidth, iAmplitude = 0, iRed, iGreen, iBlue, iBrightness, iScrollSpeed = 0, iReliable = 0) {
	message_begin(iReliable ? MSG_ALL : MSG_BROADCAST, SVC_TEMPENTITY);
	write_byte(TE_BEAMPOINTS);
	write_coord_f(fStartOrigin[0]);
	write_coord_f(fStartOrigin[1]);
	write_coord_f(fStartOrigin[2]);
	write_coord_f(fEndOrigin[0]);
	write_coord_f(fEndOrigin[1]);
	write_coord_f(fEndOrigin[2]);
	write_short(pSprite); // Индекс спрайта из прекеша (index of precached sprite)
	write_byte(iStartFrame);
	write_byte(iFrameRate); // 0.1's
	write_byte(iLife); // 0.1's
	write_byte(iWidth);
	write_byte(iAmplitude); // 0.01's
	write_byte(iRed);
	write_byte(iGreen);
	write_byte(iBlue);
	write_byte(iBrightness);
	write_byte(iScrollSpeed); // 0.1's
	message_end();
}

stock CREATE_BEAMFOLLOW(iEntity, pSptite, iLife, iWidth, iRed, iGreen, iBlue, iBrightness, iReliable = 0)
{
	message_begin(iReliable ? MSG_ALL : MSG_BROADCAST, SVC_TEMPENTITY);
	write_byte(TE_BEAMFOLLOW);
	write_short(iEntity);
	write_short(pSptite);
	write_byte(iLife); // 0.1's
	write_byte(iWidth);
	write_byte(iRed);
	write_byte(iGreen);
	write_byte(iBlue);
	write_byte(iBrightness);
	message_end();
}

// thx bizon
stock get_origin_aiming_ent(eEnt, Float: fVecDest[3] = NULL_VECTOR)
{
	static Float: fVecOrigin[3];

	get_entvar(eEnt, var_origin, fVecOrigin);
	get_entvar(eEnt, var_angles, fVecDest);

	engfunc(EngFunc_MakeVectors, fVecDest);
	global_get(glb_v_forward, fVecDest);

	xs_vec_mul_scalar(fVecDest, 8192.0, fVecDest);
	xs_vec_add(fVecOrigin, fVecDest, fVecDest);

	engfunc(EngFunc_TraceLine, fVecOrigin, fVecDest, DONT_IGNORE_MONSTERS, eEnt, 0);

	get_tr2(0, TR_vecEndPos, fVecDest);
	return get_tr2(0, TR_pHit);
}

stock get_ent_aiming(pPlayer, Float: fDist = 8192.0)
{
	static Float: fOrigin[3], Float: fDest[3];

	get_entvar(pPlayer, var_origin, fOrigin);
	get_entvar(pPlayer, var_view_ofs, fDest);

	xs_vec_add(fOrigin, fDest, fOrigin);

	get_entvar(pPlayer, var_v_angle, fDest);
	engfunc(EngFunc_MakeVectors, fDest);
	global_get(glb_v_forward, fDest);

	xs_vec_mul_scalar(fDest, fDist, fDest);
	xs_vec_add(fOrigin, fDest, fDest);

	engfunc(EngFunc_TraceLine, fOrigin, fDest, DONT_IGNORE_MONSTERS, pPlayer, 0);
	return get_tr2(0, TR_pHit);
}

stock get_player_origin_front(pPlayer, Float: vecOriginEnd[3], Float: flDist)
{
	new Float: vecData[3];

	get_entvar(pPlayer, var_origin, vecData);
	get_entvar(pPlayer, var_v_angle, vecOriginEnd);

	vecOriginEnd[0] = 0.0;

	engfunc(EngFunc_MakeVectors, vecOriginEnd);
	global_get(glb_v_forward, vecOriginEnd);

	xs_vec_mul_scalar(vecOriginEnd, flDist, vecOriginEnd);
	xs_vec_add(vecData, vecOriginEnd, vecOriginEnd);

	engfunc(EngFunc_TraceLine, vecData, vecOriginEnd, DONT_IGNORE_MONSTERS, pPlayer, 0);
	get_tr2(0, TR_vecEndPos, vecOriginEnd);
}

stock find_range_enemy(pPlayer, eEnt) {
	new iPlayers[MAX_PLAYERS];
	new iCount;
	new pVictim = NULLENT;

	switch(get_member(pPlayer, m_iTeam)) {
		case TEAM_TERRORIST: {
			get_players_ex(iPlayers, iCount,
			GetPlayers_ExcludeDead | GetPlayers_MatchTeam | GetPlayers_ExcludeHLTV | GetPlayers_IncludeConnecting,
				"CT"
			);
		}
		case TEAM_CT: {
			get_players_ex(iPlayers, iCount,
				GetPlayers_ExcludeDead | GetPlayers_MatchTeam | GetPlayers_ExcludeHLTV | GetPlayers_IncludeConnecting,
				"TERRORIST"
			);
		}
		default: {
			return pVictim;
		}
	}

	new Float: flVecOriginCopter[3], Float: flVecOriginPlayer[3];
	get_entvar(eEnt, var_origin, flVecOriginCopter);

	for(new i, id, Float: flMinDist = 9999.0, Float: flDist; i < iCount; i++) {
		id = iPlayers[i];

		get_entvar(id, var_origin, flVecOriginPlayer);
		engfunc(EngFunc_TraceLine, flVecOriginCopter, flVecOriginPlayer, DONT_IGNORE_MONSTERS, eEnt, 0);

		if(get_tr2(0, TR_pHit) != id)
			continue;

		flDist = get_distance_f(flVecOriginCopter, flVecOriginPlayer);

		if(flDist < flMinDist) {
			flMinDist = flDist;
			pVictim = id;
		}
	}

	return pVictim;
}

stock bool: is_hull_vacant(Float: flVecOrigin[3], iHull, eEnt)
{
	engfunc(EngFunc_TraceHull, flVecOrigin, flVecOrigin, DONT_IGNORE_MONSTERS, iHull, eEnt, 0);
 
	return !get_tr2(0, TR_StartSolid) && !get_tr2(0, TR_AllSolid) && get_tr2(0, TR_InOpen);
}

Версия	Дата выхода	Размер	Скачиваний	Скачать
0.2	25 дек 2025, 20:23	223.96 КБ	2	Copter_0.2.zip
0.2	21 дек 2025, 21:04	221.35 КБ	0	Copter.zip

Кто сейчас на конференции

Зарегистрированные пользователи: Ahrefs [Bot], Линар Зарипов

Место свободно

Здесь вы сможете купить рекламу на данном форуме

Стоимость за 1 день 10 ₽

Copter | Коптер

Версия: 0.2 25.12.2025 20:23

Версия: 0.2 21.12.2025 21:04

Copter | Коптер - обновление

Кто сейчас на конференции