Код: Выделить всё

#include <amxmodx>
#include <reapi>
#include <hamsandwich>

new const g_szVerionPlugin[] = "0.1";

new bool: g_bIsCameraGrenadeView[MAX_PLAYERS+1];
new bool: g_bIsShowInfo[MAX_PLAYERS+1], Float: g_flShowInfoTime[MAX_PLAYERS+1];
new g_eGrenadeThrowCashed[MAX_PLAYERS+1];

public client_disconnected(pPlayer) {
	g_bIsCameraGrenadeView[pPlayer] = false;
	g_bIsShowInfo[pPlayer] = false;
}

public plugin_init() {
	register_plugin("Camera behind grenade", g_szVerionPlugin, "Kurtis");

	RegisterHookChain(RG_CBasePlayer_Spawn, "CBasePlayer_Spawn_Post", 1);
	RegisterHookChain(RG_CBasePlayer_Killed, "CBasePlayer_Killed_Post", 1);
	RegisterHookChain(RG_CBasePlayer_TakeDamage, "CBasePlayer_TakeDamage_Post", 1);
	RegisterHookChain(RG_CBasePlayer_PreThink, "CBasePlayer_PreThink", 1);

	RegisterHookChain(RG_CBasePlayer_ThrowGrenade, "CBasePlayer_ThrowGrenade_Post", 1);
	RegisterHookChain(RG_CGrenade_ExplodeHeGrenade, "CGrenade_ExplodeHeGrenade_Pre");
	RegisterHookChain(RG_CGrenade_ExplodeFlashbang, "CGrenade_ExplodeFlashbang_Pre");
	RegisterHookChain(RG_CGrenade_ExplodeSmokeGrenade, "CGrenade_ExplodeSmokeGrenade_Pre");

	RegisterHookChain(RG_CBasePlayerWeapon_DefaultDeploy, "CBasePlayerWeapon_DefaultDeploy_Pre");

	RegisterHam(Ham_Weapon_SecondaryAttack, "weapon_hegrenade", "CBasePlayerWeapon_SecondaryAttack_Post");
	RegisterHam(Ham_Weapon_SecondaryAttack, "weapon_flashbang", "CBasePlayerWeapon_SecondaryAttack_Post");
	RegisterHam(Ham_Weapon_SecondaryAttack, "weapon_smokegrenade", "CBasePlayerWeapon_SecondaryAttack_Post");
}

public CBasePlayer_Spawn_Post(pPlayer) {
	if(!is_user_connected(pPlayer)) {
		return;
	}

	g_bIsShowInfo[pPlayer] = false;

	_reset_view(pPlayer);
}

public CBasePlayer_Killed_Post(pVictim, pKiller, iCorpse) {
	if(!is_user_connected(pVictim)) {
		return;
	}

	_reset_view(pVictim);
}

public CBasePlayer_TakeDamage_Post(pVictim, iInflictor, pAttacker, Float: flDamage, dmgBit) {
	if(!is_user_connected(pVictim) || !g_bIsShowInfo[pVictim] || g_eGrenadeThrowCashed[pVictim] == NULLENT) {
		return;
	}

	_reset_view(pVictim);
}

public CBasePlayer_PreThink(pPlayer) {
	if(!is_user_alive(pPlayer) || !g_bIsShowInfo[pPlayer] || g_eGrenadeThrowCashed[pPlayer] == NULLENT) {
		return;
	}

	if(~get_entvar(pPlayer, var_button) & IN_ATTACK2) {
		return;
	}

	_reset_view(pPlayer);

	g_flShowInfoTime[pPlayer] = get_gametime() + 1.5;
}

public CBasePlayer_ThrowGrenade_Post(pPlayer, iGrenade, Float: vecSrc[3], Float: vecThrow[3], Float: flTime, usEvent) {

	if(!is_user_connected(pPlayer) || !g_bIsCameraGrenadeView[pPlayer]) {
		return;
	}

	if(is_nullent(iGrenade)) {
		return;
	}

	g_eGrenadeThrowCashed[pPlayer] = GetHookChainReturn(ATYPE_INTEGER);

	if(is_nullent(g_eGrenadeThrowCashed[pPlayer])) {
		return;
	}

	engset_view(pPlayer, g_eGrenadeThrowCashed[pPlayer]);
}

public CGrenade_ExplodeHeGrenade_Pre(eEnt, tracehandle, const bitsDamageType) {
	_reset_grenade_view(eEnt);
}

public CGrenade_ExplodeFlashbang_Pre(eEnt, tracehandle, const bitsDamageType) {
	_reset_grenade_view(eEnt);
}

public CGrenade_ExplodeSmokeGrenade_Pre(eEnt) {
	_reset_grenade_view(eEnt);
}

public CBasePlayerWeapon_DefaultDeploy_Pre(iItem, const szViewModel[], const szWeaponModel[], iAnim, const szAnimExt[], skiplocal) {
	if(is_nullent(iItem)) {
		return;
	}

	new WeaponIdType: iId = get_member(iItem, m_iId);

	if(iId != WEAPON_HEGRENADE && iId != WEAPON_FLASHBANG && iId != WEAPON_SMOKEGRENADE) {
		return;
	}

	new pPlayer = get_member(iItem, m_pPlayer);

	if(!is_user_connected(pPlayer) || g_bIsShowInfo[pPlayer]) {
		return;
	}

	g_bIsShowInfo[pPlayer] = true;

	client_print(pPlayer, print_center, "Для переключения режима слежения за гранатой нажмите ПКМ");
}

public CBasePlayerWeapon_SecondaryAttack_Post(iItem) {
	if(is_nullent(iItem)) {
		return;
	}

	new pPlayer = get_member(iItem, m_pPlayer);

	if(!is_user_connected(pPlayer)) {
		return;
	}

	new Float: flGameTime = get_gametime();

	if(flGameTime < g_flShowInfoTime[pPlayer]) {
		return;
	}

	g_flShowInfoTime[pPlayer] = flGameTime + 1.5;

	g_bIsCameraGrenadeView[pPlayer] = !g_bIsCameraGrenadeView[pPlayer];
	client_print(pPlayer, print_center, "Режим слежения за гранатой в%sключен", g_bIsCameraGrenadeView[pPlayer] ? NULL_STRING : "ы");
}

public _reset_grenade_view(eEnt) {
	if(is_nullent(eEnt)) {
		return;
	}

	new pPlayer = get_entvar(eEnt, var_owner);

	if(!is_user_connected(pPlayer)) {
		return;
	}

	_reset_view(pPlayer);
}

public _reset_view(pPlayer) {
	g_eGrenadeThrowCashed[pPlayer] = NULLENT;

	engset_view(pPlayer, pPlayer);
}

Код: Выделить всё

#include <amxmodx>
#include <reapi>
#include <hamsandwich>